<<MB/MB.m;
<<MB/MBresolve.m

(*   The integrand of the MB integral for the one-loop propagator diagram with m1=m and m2=0 *)

MB[a1_,a2_]:=(-1)^(a1+a2)/QQ^(a1+a2+ep-2)/Gamma[a1]/Gamma[a2] Gamma[2-ep-a2]Gamma[a1+a2+ep-2+z]Gamma[2-ep-a1-z]Gamma[-z]/Gamma[4-2ep-a1-a2-z]mm^z/QQ^z;

(*  Notation: mm=m^2, QQ=-q^2;
I Pi^(d/2) is pulled out  *)

(*  The diagram with a1=1 and a2=1  *)

P1=MB[1,1]

MBresolve[P1,ep]

Box1[a1_,a2_,a3_,a4_] :=
((S^(2-a1-a2-a3-a4-ep-z)) (T^z) Gamma[a1+a2+a3+a4-2+ep+z]Gamma[a2+z] Gamma[a4+z] Gamma[2-a1-a2-a4-ep-z] Gamma[2-a2-a3-a4-ep-z] Gamma[-z] )/(Gamma[a1] Gamma[a2] Gamma[a3] Gamma[a4] Gamma[4-a1-a2-a3-a4-2 ep]);

Box1[1,1,1,1]

B1=% /. {S->1,T->x}

MBresolve[B1,ep]

NPMB[a1_,a2_,a3_,a4_,a5_,a6_]:=((-1)^(a1+a2+a3+a4+a5+a6)/(Gamma[a1]Gamma[a2]Gamma[a3]Gamma[a4]Gamma[a5]Gamma[a6])Gamma[2-ep-a3-a5]Gamma[2-ep-a4-a6]/Gamma[4-2ep-a3-a4-a5-a6]/Gamma[6-3ep-a1-a2-a3-a4-a5-a6]
Gamma[a1+a2+a3+a4+a5+a6+2ep-4+z1+z2]Gamma[-z1]Gamma[-z2]Gamma[2-ep-a1-a2-z1]Gamma[a4+z2]Gamma[a1+z1+z2]Gamma[4-2ep-a1-a3-a4-a5-a6-z2]Gamma[4-2ep-a1-a2-a4-a5-a6-z1-z2]Gamma[a5+z2]Gamma[4-2ep-a1-a2-a3-a4-a5-z1-z2]/Gamma[4-2ep-a1-a2-a4-a6-z1]/Gamma[4-2ep-a1-a2-a3-a5-z1]);

V2=NPMB[1,1,1,1,1,1]

MBresolve[V2,ep]

Simplify[%]

(*      Example  4a     *)

F=Gamma[3/2+ep+z] Gamma[-1-2 ep-z] Gamma[4 ep+z]Gamma[-z] Gamma[1/2-ep-z] /Gamma[1-2 ep-z]

MBresolve[F,ep]

MBmerge[%]

(*      Example  4b     *)

F=Gamma[-1/2+ep+z] Gamma[1+ ep+z] Gamma[3/2-ep-z] Gamma[-z]

MBresolve[F,ep]