<<MB/MB.m

(*   2fold MB representation for the non-planar vertex massless diagram. 
The factor (QQ^(4-a1-a2-a3-a4-a5-a6-2 ep)) is omitted. 
QQ=-(p1-p2)^2.
The factor (I Pi^(d/2))^2 is also omitted as usually.  *)

NPMB[a1_,a2_,a3_,a4_,a5_,a6_]:=((-1)^(a1+a2+a3+a4+a5+a6)/(Gamma[a1]Gamma[a2]Gamma[a3]Gamma[a4]Gamma[a5]Gamma[a6])Gamma[2-ep-a3-a5]Gamma[2-ep-a4-a6]/Gamma[4-2ep-a3-a4-a5-a6]/Gamma[6-3ep-a1-a2-a3-a4-a5-a6]
Gamma[a1+a2+a3+a4+a5+a6+2ep-4+z1+z2]Gamma[-z1]Gamma[-z2]Gamma[2-ep-a1-a2-z1]Gamma[a4+z2]Gamma[a1+z1+z2]Gamma[4-2ep-a1-a3-a4-a5-a6-z2]Gamma[4-2ep-a1-a2-a4-a5-a6-z1-z2]Gamma[a5+z2]Gamma[4-2ep-a1-a2-a3-a4-a5-z1-z2]/Gamma[4-2ep-a1-a2-a4-a6-z1]/Gamma[4-2ep-a1-a2-a3-a5-z1]);

(*   The diagram with all powers of the propagators equal to one. We shall evaluate it in expansion in ep up to ep^0. *)

V2=NPMB[1,1,1,1,1,1]

V2rules=MBoptimizedRules[V2,ep->0,{},{ep}]

V2cont=MBcontinue[V2,ep->0,V2rules];

V2select=MBpreselect[MBmerge[V2cont],{ep,0,0}]

V2exp=Simplify[MBexpand[V2select,Exp[2ep EulerGamma],{ep,0,0}]]

Length[V2exp]

res1=V2exp[[1]][[1]]

V2exp[[3]]

Barnes1[V2exp[[3]],z1]

res2=Barnes1[%,z2][[1]]

V2exp[[2]]

CoeffEps[X_,n_]:=(X /.X[[1]]-> Simplify[Coefficient[X[[1]],ep,n]]);

CoeffEps[V2exp[[2]],-2]

res32=Barnes1[CoeffEps[V2exp[[2]],-2],z1][[1]]

CoeffEps[V2exp[[2]],-1]

res31=9 Zeta[3];

res31//N

NIntegrate[CoeffEps[V2exp[[2]],-1][[1]]/(2Pi)  /.{z1->-(1/4)+I*y1},{y1,-Infinity,Infinity}]

CoeffEps[V2exp[[2]],0]

res30=((7 (π^4))/10);

res30//N

NIntegrate[CoeffEps[V2exp[[2]],0][[1]]/(2Pi)  /.{z1->-(1/4)+I*y1},{y1,-Infinity,Infinity}]

(*         result      *)

FullSimplify[res1+res2+res32/ep^2+res31/ep+res30]